Tidy CVS

Randy McMurchy randy at linuxfromscratch.org
Mon Mar 26 17:14:58 PDT 2007


Bruce Dubbs wrote these words on 03/26/07 19:00 CST:

> running: aclocal
> /usr/share/aclocal/xmms.m4:17: warning: underquoted definition of
> XMMS_TEST_VERSION
>   run info '(automake)Extending aclocal'
>   or see http://sources.redhat.com/automake/automake.html#Extending-aclocal
> /usr/share/aclocal/xmms.m4:62: warning: underquoted definition of
> AM_PATH_XMMS
> /usr/share/aclocal/speex.m4:10: warning: underquoted definition of
> XIPH_PATH_SPEEX
> /usr/share/aclocal/nspr.m4:8: warning: underquoted definition of
> AM_PATH_NSPR
> /usr/share/aclocal/libfame.m4:6: warning: underquoted definition of
> AM_PATH_LIBFAME
> /usr/share/aclocal/imlib.m4:9: warning: underquoted definition of
> AM_PATH_IMLIB
> /usr/share/aclocal/imlib.m4:167: warning: underquoted definition of
> AM_PATH_GDK_IMLIB
> /usr/share/aclocal/gtk.m4:7: warning: underquoted definition of AM_PATH_GTK
> /usr/share/aclocal/glib.m4:8: warning: underquoted definition of
> AM_PATH_GLIB
> /usr/share/aclocal/audiofile.m4:12: warning: underquoted definition of
> AM_PATH_AUDIOFILE
> /usr/share/aclocal/aalib.m4:12: warning: underquoted definition of
> AM_PATH_AAL
> 
> I do get the underquoted warnings every time I run autotools.

It is not a coincidence that on May 31 last year the following files
were modified (a different partition than my current one):

rml at rmlinux: /mnt/rml2/usr/share/aclocal > ls -rlt
-rw-r--r-- 1 root root   5553 May 31  2006 xmms.m4
-rw-r--r-- 1 root root   3704 May 31  2006 speex.m4
-rw-r--r-- 1 root root   8561 May 31  2006 libfame.m4
-rw-r--r-- 1 root root   8287 May 31  2006 gtk.m4
-rw-r--r-- 1 root root   8444 May 31  2006 glib.m4
-rw-r--r-- 1 root root   6793 May 31  2006 audiofile.m4
-rw-r--r-- 1 root root   6296 May 31  2006 aalib.m4

Notice how the names of these files coincide with many of the ones you
show. This is because those .m4 files are indeed wrong. But you can fix
them. We should probably be patching this in BLFS. Anyway, I'm adding
in-line my speex.m4 file. Diff it to yours and you'll see the "underquoted
definition" fixed. :-)

Then, you'll see what you need to do with the others to fix them. It's
all the same issue. And the issue is upstream with each individual
package that installs the .m4 files.



# Configure paths for libspeex
# Jean-Marc Valin <jean-marc.valin at usherbrooke.ca>
# Shamelessly stolen from:
# Jack Moffitt <jack at icecast.org> 10-21-2000
# Shamelessly stolen from Owen Taylor and Manish Singh

dnl XIPH_PATH_SPEEX([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
dnl Test for libspeex, and define SPEEX_CFLAGS and SPEEX_LIBS
dnl
AC_DEFUN([XIPH_PATH_SPEEX],
[dnl
dnl Get the cflags and libraries
dnl
AC_ARG_WITH(speex,[  --with-speex=PFX   Prefix where libspeex is installed (optional)], speex_prefix="$withval", speex_prefix="")
AC_ARG_WITH(speex-libraries,[  --with-speex-libraries=DIR   Directory where libspeex library is installed (optional)], speex_libraries="$withval", speex_libraries="")
AC_ARG_WITH(speex-includes,[  --with-speex-includes=DIR   Directory where libspeex header files are installed (optional)], speex_includes="$withval", speex_includes="")
AC_ARG_ENABLE(speextest, [  --disable-speextest       Do not try to compile and run a test Speex program],, enable_speextest=yes)

  if test "x$speex_libraries" != "x" ; then
    SPEEX_LIBS="-L$speex_libraries"
  elif test "x$speex_prefix" != "x" ; then
    SPEEX_LIBS="-L$speex_prefix/lib"
  elif test "x$prefix" != "xNONE" ; then
    SPEEX_LIBS="-L$prefix/lib"
  fi

  SPEEX_LIBS="$SPEEX_LIBS -lspeex"

  if test "x$speex_includes" != "x" ; then
    SPEEX_CFLAGS="-I$speex_includes"
  elif test "x$speex_prefix" != "x" ; then
    SPEEX_CFLAGS="-I$speex_prefix/include"
  elif test "x$prefix" != "xNONE"; then
    SPEEX_CFLAGS="-I$prefix/include"
  fi

  AC_MSG_CHECKING(for Speex)
  no_speex=""


  if test "x$enable_speextest" = "xyes" ; then
    ac_save_CFLAGS="$CFLAGS"
    ac_save_LIBS="$LIBS"
    CFLAGS="$CFLAGS $SPEEX_CFLAGS"
    LIBS="$LIBS $SPEEX_LIBS"
dnl
dnl Now check if the installed Speex is sufficiently new.
dnl
      rm -f conf.speextest
      AC_TRY_RUN([
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <speex/speex.h>

int main ()
{
  system("touch conf.speextest");
  return 0;
}

],, no_speex=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
       CFLAGS="$ac_save_CFLAGS"
       LIBS="$ac_save_LIBS"
  fi

  if test "x$no_speex" = "x" ; then
     AC_MSG_RESULT(yes)
     ifelse([$1], , :, [$1])
  else
     AC_MSG_RESULT(no)
     if test -f conf.speextest ; then
       :
     else
       echo "*** Could not run Speex test program, checking why..."
       CFLAGS="$CFLAGS $SPEEX_CFLAGS"
       LIBS="$LIBS $SPEEX_LIBS"
       AC_TRY_LINK([
#include <stdio.h>
#include <speex/speex.h>
],     [ return 0; ],
       [ echo "*** The test program compiled, but did not run. This usually means"
       echo "*** that the run-time linker is not finding Speex or finding the wrong"
       echo "*** version of Speex. If it is not finding Speex, you'll need to set your"
       echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
       echo "*** to the installed location  Also, make sure you have run ldconfig if that"
       echo "*** is required on your system"
       echo "***"
       echo "*** If you have an old version installed, it is best to remove it, although"
       echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
       [ echo "*** The test program failed to compile or link. See the file config.log for the"
       echo "*** exact error that occured. This usually means Speex was incorrectly installed"
       echo "*** or that you have moved Speex since it was installed." ])
       CFLAGS="$ac_save_CFLAGS"
       LIBS="$ac_save_LIBS"
     fi
     SPEEX_CFLAGS=""
     SPEEX_LIBS=""
     ifelse([$2], , :, [$2])
  fi
  AC_SUBST(SPEEX_CFLAGS)
  AC_SUBST(SPEEX_LIBS)
  rm -f conf.speextest
])



-- 
Randy

rmlscsi: [bogomips 1003.28] [GNU ld version 2.16.1] [gcc (GCC) 4.0.3]
[GNU C Library stable release version 2.3.6] [Linux 2.6.14.3 i686]
19:03:00 up 17 days, 17:02, 1 user, load average: 0.17, 0.05, 0.01



More information about the blfs-dev mailing list